TSET 1,15
ONTIMER 1,"GOTO JavaCheck"

JavaCheck:
IF @IsJavaActive%() < 1 THEN
  GETHTTP "adm:adm@192.168.120.92", "/usr/temp.txt","/rcgi.bin/jvmCmd?cmd=start&runCmd=%20-heapsize%205M%20-classpath%20/usr/Test.jar%20-emain%20MainClass"
  PRINT "Java Stopped --> Restarted"
  LOGEVENT "Java Stopped --> Restarted", 100
ELSE
  PRINT "Java Still running"
ENDIF
END

Function IsJavaActive%()
  OPEN "exp:$dtEV" FOR TEXT INPUT AS 1
  $TitleLine% = 0
  $StartJavaNumber% = 0
  $StopJavaNumber% = 0
  $IsJavaActive% = 0

  $ReadNext:
    IF EOF 1 THEN GOTO $ReadDone
    $Line$ = GET 1
    IF $TitleLine% = 1 And $Line$ <> "" THEN

      $EvtCode% = VAL @SplitString$($Line$, 6, ";", 0)
      IF $EvtCode% = 1073774552 THEN $StopJavaNumber% = $StopJavaNumber% + 1 
      IF $EvtCode% = 1073774551 THEN $StartJavaNumber% = $StartJavaNumber% + 1 
      IF $EvtCode% = -22602 THEN $StartJavaNumber% = 0 : $StopJavaNumber% = 0 //reset counters when reboot log is seen
    ELSE
     $TitleLine% = 1
    ENDIF
    GOTO $ReadNext
    $ReadDone:
  $IsJavaActive% = $StartJavaNumber% - $StopJavaNumber%
  CLOSE 1
EndFn


Function SplitString$ ($StringToParse$,$Pos%, $char$, $RemoveQuotes%)
$e% = 1
$loopnbr% = 0
$NextItem:
 $f% = INSTR $e% , $StringToParse$ , $char$
 //LAST ELEMENT
 IF $f% = 0 THEN  
    $B$ = $StringToParse$( $e% TO LEN $StringToParse$-2)
    IF $Pos% > $loopnbr% + 1 THEN $SplitString$ = "!OutOfRange!" : GOTO $EndOfFunction
    GOTO $EndOfLine        
 ENDIF
 $loopnbr% = $loopnbr% + 1
 $B$ = $StringToParse$( $e% TO $f%-1)
 IF $Pos% = $loopnbr% THEN GOTO $EndOfLine
 $e% = $f% + 1 //REM Init for next loop/line            
 GOTO $NextItem
$EndOfLine:
IF ($RemoveQuotes% = 0) THEN $SplitString$ = $B$ ELSE $SplitString$ = $B$(2 TO LEN $B$-1)
$EndOfFunction:
EndFn